Siempre a tiempo con los módulos de reloj de tiempo REAL DS1307 y DS3231

Colocado en 2016-07-16

Módulos de reloj de tiempo REAL

Versiones de reloj en tiempo REAL

La serie de relojes de tiempo REAL contiene muchos tipos de números diferentes, todos con una funcionalidad comparable. En esta serie, solo 2 versiones son 'mainstream', a saber, la DS1307 y el DS3231. Estos chips tienen la opción de conectar una batería y tienen un pin de salida sqw, con el cual el controlador puede recibir un pulso de reloj de (1Hz, 1.024kHz, 4.096kHz, 8.192kHz). Ambos circuitos integrados también tienen una interfaz One-Wire, lo que hace posible conectarlos a través de I²para dirigirse a c

Módulo de reloj de tiempo REAL DS1302 - SPIEl módulo de reloj de tiempo REAL DS1302 tiene una interfaz SPI a través de la cual puede decir la hora. En stock € 1,85

Módulo de reloj en tiempo REAL DS3231Módulo de reloj en tiempo REAL con chip DS3231. Este módulo asegura que Arduino sepa la hora exacta en todo momento. Conectando el Arduino al pin 'sqw' es posible generar una interrupción cada segundo con la que se pueden direccionar los valores de un sensor o un display. En stock € 3,95

Conexión del módulo RTC al Arduino UNO

Los módulos RTC vienen en diferentes formas y tamaños, pero la conexión al Arduino es la misma para todos los módulos. En cualquier caso, el módulo debe estar alimentado con 5V, además, la interfaz I2C deberá estar conectada a los pines SDA (Serial data) SCL (Serial clock) del Arduino (estos son los pines A4 y A5 en el Arduino UNO). Además, la salida SQW se puede conectar a cualquier pin del Arduino para recibir un pulso de reloj del RTC.

Conexión DS1307 Arduino UNO

Código BC

Los valores numéricos en los chips RTC se almacenan en formato BCD. El código BCD es más fácil de usar que los números decimales a nivel de hardware, pero estos códigos no son muy útiles en el software. Por lo tanto, los números hacia y desde el chip deben codificarse y decodificarse para que el controlador y el RTC se entiendan entre sí.

// Convert decimal to BCD
byte decToBcd(byte val)
{
  return( (val/10*16) + (val%10) );
}
//Convert BCD to decimal
byte bcdToDec(byte val)
{
  return( (val/16*10) + (val%16) );
}

Escribe la hora actual en el RTC

Solo es necesario escribir la hora en el RTC una vez cuando está conectado a la batería. El propio RTC mantiene el tiempo y continúa contando, incluso cuando no está conectado al controlador.

#include "Wire.h"
#define DS3231_I2C_ADDRESS 0x68

void setDS3231time(
    byte second, 
    byte minute, 
    byte hour, 
    byte dayOfWeek, 
    byte dayOfMonth, 
    byte month, 
    byte year)
{
  Wire.beginTransmission(DS3231_I2C_ADDRESS);
  
  //set next input to start at the seconds register
  Wire.write(0); 
  
  //set seconds
  Wire.write(decToBcd(second)); 
  //set minutes
  Wire.write(decToBcd(minute)); 
  //set hours
  Wire.write(decToBcd(hour)); 
  //set day of week (1=Sunday, 7=Saturday)
  Wire.write(decToBcd(dayOfWeek));  
  //set date (1 to 31)
  Wire.write(decToBcd(dayOfMonth)); 
  //set month
  Wire.write(decToBcd(month));
  //set year 20(0 to 99)
  Wire.write(decToBcd(year)); 
    
  Wire.endTransmission();
}

reloj del disco duro

De tijd van de RTC lezen

#include "Wire.h"
#define DS3231_I2C_ADDRESS 0x68

void readDS3231time(
    byte *second,
	byte *minute,
	byte *hour,
	byte *dayOfWeek,
	byte *dayOfMonth,
	byte *month,
	byte *year)
{
  Wire.beginTransmission(DS3231_I2C_ADDRESS);
  //set DS3231 register pointer to 00h
  Wire.write(0); 
  Wire.endTransmission();
      
  //request seven bytes of data from DS3231
  Wire.requestFrom(DS3231_I2C_ADDRESS, 7);
  *second = bcdToDec(Wire.read() & 0x7f);
  *minute = bcdToDec(Wire.read());
  *hour = bcdToDec(Wire.read() & 0x3f);
  *dayOfWeek = bcdToDec(Wire.read());
  *dayOfMonth = bcdToDec(Wire.read());
  *month = bcdToDec(Wire.read());
  *year = bcdToDec(Wire.read());
}

mostrar la hora

Con estas funciones juntas, el Arduino puede determinar el tiempo. Con la función a continuación, estos datos se escriben en el monitor serie, pero las posibilidades de mostrar la hora son infinitas.

void setup()
{
  Wire.begin();
  Serial.begin(9600);
  
  //set the initial time (only once, not every startup)
  //seconds, minutes, hours, dayofweek, day, month, year
  //11:00:00, Saturday, 2016-07-16
  setDS3231time(00,00,11,7,16,7,16);
}

void displayTime()
{
  byte second, minute, hour; 
  byte dayOfWeek, dayOfMonth, month, year;
  
  //retrieve data
  readDS3231time(&second, &minute, &hour, &dayOfWeek, 				     &dayOfMonth, &month, &year);
    
  //Hour
  Serial.print(hour, DEC);
  Serial.print(":");
  //Minute (+0 if needed)
  if (minute<10)
  {
    Serial.print("0");
  }
  Serial.print(minute, DEC);
  Serial.print(":");
  //Second (+0 if needed)
  if (second<10)
  {
    Serial.print("0");
  }
  Serial.print(second, DEC);
  Serial.print(" ");
    
  //Day
  Serial.print(dayOfMonth, DEC);
  Serial.print("/");
  //Month
  Serial.print(month, DEC);
  Serial.print("/");
  //Year
  Serial.print(year, DEC);
}


void loop()
{
  displayTime(); 
  delay(1000);
}

SQW frequentie instellen

#include "Wire.h"
#define DS3231_I2C_ADDRESS 0x68

void setup()
{
  Wire.begin();
  Serial.begin(9600);
  
  Wire.beginTransmission(DS3231_I2C_ADDRESS);
  
  //move pointer to SQW address
  Wire.write(0x07); 
 
  //set output clock speed
  //0x00 = Off
  //0x10 = 1Hz
  //0x11 = 4.096Hz
  //0x12 = 8.192Hz
  //0x13 = 32.768Hz
  Wire.write(0x10);
 
  Wire.endTransmission();  
}

Con este código se puede construir un reloj completo, que puede mostrar la hora. Esto se puede hacer en una pantalla de 7 segmentos, como un reloj analógico, con señales de humo o incluso se puede hablar cuando se lo solicite. Además, el tiempo también se puede utilizar en domótica / domótica, la cafetera se enciende por la mañana a las 8 am, el microondas a las 5.15 pm por la noche y las cortinas se cierran a las 7.01:05 pm. Todo es posible.

Publicado por Robin Blok Sitio web Me interesa la electrónica, la programación y sobre todo la combinación de ambas. Para Opencircuit escribo blogs en los que explico cómo funcionan la electrónica y los módulos.