Probador Arduino Uno como 74HC4051 (MUX/DEMUX)

Colocado en 2019-10-04

Prueba 74HC4051

El 74HC4051 es un CI multiplexor/demultiplexor. Para probar esto, el Arduino Uno se puede usar con dos circuitos integrados 74HC4051. El primer IC actúa como multiplexor, el segundo como demultiplexor.

asignación de pines

Alfiler	Etiqueta	Función
1	A4	Canal de entrada/salida
2	A6	Canal de entrada/salida
3	A	entrada/salida común
4	A7	Canal de entrada/salida
5	A5	Canal de entrada/salida
6	~E	Habilitar (negativo)
7	Ganado	Fuente de alimentación negativa
8	TIERRA	Tierra (0V)
9	vcc	Fuente de alimentación (5 V CC)
10	A2	Canal de entrada/salida
11	A1	Canal de entrada/salida
12	A0	Canal de entrada/salida
13	A3	Canal de entrada/salida
14	S0	Línea de dirección bit 0
15	S1	Línea de dirección bit 1
16	S2	Línea de dirección bit 2

Pruebas digitales

Aunque el 74HC4051 es un MUX/DEMUX analógico, no se puede probar de forma analógica con el Arduino Uno ya que no tiene salidas analógicas (DAC). Más adelante en este artículo, se describe cómo se puede lograr esto con una placa de conexión DAC. Para probar digitalmente, solo se necesita la placa Arduino y 2 circuitos integrados.

Conectar

Establezca el pin 16 (Vcc) de ambos circuitos integrados en 5 VCC; pin 8 (GND) a 0V.

Conecte también los pines 6 (~E) y 7 (Vee) de ambos circuitos integrados a GND.

Conecte los siguientes pines de ambos circuitos integrados: 1,2,4,5,15,16,13,12 (A0..A7).

Conecte los pines 11 (S0) de ambos circuitos integrados a la placa Arduino en A0.

Conecte el pin 12 (S1) de ambos circuitos integrados a la placa Arduino en A1.

Conecte los pines 13 (S2) de ambos circuitos integrados a la placa Arduino en A2.

Desde IC 1, conecte el pin 3 (A) a la placa Arduino en A4.

Desde IC 2, conecte el pin 3 (A) a la placa Arduino en A5.

codigo Arduino

Use el siguiente código para el Arduino

Test 74HC4051 MUX/DEMUX met Arduino Uno

/****************************************************************
      Configuratie
****************************************************************/
#define pinS0   A0 // Address select 0
#define pinS1   A1 // Address select 1
#define pinS2   A2 // Address select 2
#define pinA_ic1  A4    // A pin on IC1
#define pinA_ic2  A5    // A pin on IC2
/*****   EINDE CONFIGUTATIE    *****/

// Poll timer
unsigned long lastPoll;

/****************************************************************
      SETUP
****************************************************************/
void setup()
{
  Serial.begin(115200);
  while (!Serial) {
    ; // Wacht op seriele monitor
  }
  Serial.println("--- Seriele monitor gestart ---");

  // Configureer pinnen als uitgangen
  pinMode(pinS0, OUTPUT);
  pinMode(pinS1, OUTPUT);
  pinMode(pinS2, OUTPUT);
  pinMode(pinA_ic1, OUTPUT);
  // Configureer pinnen als ingangen
  pinMode(pinA_ic2, INPUT);

  lastPoll = millis();
}

/****************************************************************
      LOOP
****************************************************************/
void loop()
{
  static byte byteCounter = 0;
  static bool writeBit;
  static bool readBit;
  String testResult;

  // Genereer willekeurig true of false
  writeBit = bool(random(0, 2));

  // Elke 500ms
  if (millis() - lastPoll >= 500)
  {
    // Selecteer adres
    selectAddress(byteCounter);

    // Schrijf bit naar IC 1
    digitalWrite(pinA_ic1, writeBit);

    // Lees bit van IC 2
    readBit = digitalRead(pinA_ic2);

    if (writeBit == readBit) {
      testResult = " -> OK";
    }
    else {
      testResult = " -> NIET OK";
    }
    

    // In de seriële monitor moet bit schrijf = bit lees
    Serial.print("Op adres " );
    Serial.print(byteCounter, BIN);
    Serial.print(" is schrijf (IC 1) vs lees (IC 2): " );
    Serial.print(writeBit);
    Serial.print(" / ");
    Serial.print(readBit);
    Serial.print(testResult);
    Serial.println();

    // Selecteer volgend adres 
    byteCounter++;
    if (byteCounter > 7) {
      byteCounter = 0;  // Reset counter at 1000 (count 0000 to 0111)
    }
    lastPoll = millis();
  }
}

/****************************************************************
      Zet de Sx pinnen om het gewenste adres te selecteren
****************************************************************/
void selectAddress(byte address) {
  // Lees adres bits
  bool S0 = bool(address >> 0 & 0x01); // Shift rechts en maskeer met 0x01
  bool S1 = bool(address >> 1 & 0x01);
  bool S2 = bool(address >> 2 & 0x01);

  // Zet adres lijnen correct
  digitalWrite(pinS0, S0);
  digitalWrite(pinS1, S1);
  digitalWrite(pinS2, S2);
}
//EINDE

El resultado es algo de este género:

Op adres 0 is schrijf (IC 1) vs lees (IC 2): 1 / 1 -> OK
Op adres 1 is schrijf (IC 1) vs lees (IC 2): 0 / 0 -> OK
Op adres 10 is schrijf (IC 1) vs lees (IC 2): 0 / 0 -> OK
Op adres 11 is schrijf (IC 1) vs lees (IC 2): 1 / 1 -> OK
Op adres 100 is schrijf (IC 1) vs lees (IC 2): 0 / 0 -> OK
Op adres 101 is schrijf (IC 1) vs lees (IC 2): 0 / 0 -> OK
Op adres 110 is schrijf (IC 1) vs lees (IC 2): 1 / 1 -> OK
Op adres 111 is schrijf (IC 1) vs lees (IC 2): 0 / 0 -> OK
Op adres 0 is schrijf (IC 1) vs lees (IC 2): 0 / 0 -> OK
Op adres 1 is schrijf (IC 1) vs lees (IC 2): 1 / 1 -> OK
Op adres 10 is schrijf (IC 1) vs lees (IC 2): 1 / 1 -> OK
Op adres 11 is schrijf (IC 1) vs lees (IC 2): 0 / 0 -> OK

Componentes

Los componentes para esta prueba:

Lista de componentes

Multiplexor 74HC4051 - 5 piezas Agotado (vendido por 5) € 3,60 Protoboard 400 puntos - blanco Agotado € 1,90 Conjunto jersey macho-masculino 65 piezas Agotado € 2,95 Total € 8,45

De la misma manera, puede probar la versión en el tablero de conexiones

Salida de multiplexor Sparkfun - 8 canales (74HC4051)Libere todo el potencial del 74HC4051 con Sparkfun Multiplexer Breakout. Transforme cuatro pines de E/S en ocho señales seleccionables, adecuadas para una variedad de aplicaciones. Fácil de usar, fiable y versátil tanto para aficionados como para profesionales. En stock € 4,10

Pruebas analógicas

Para probar analógico necesitas un DAC. El Arduino Uno no tiene esto como estándar, pero con la ayuda de la placa de conexión " Adafruit MCP4725 (12bit DAC)", posiblemente pueda lograrlo.

Placa de conexiones MCP4725 - DAC de 12 bits con interfaz I2CSu microcontrolador probablemente tenga un ADC (convertidor analógico -> digital), pero ¿tiene un DAC (convertidor digital -> analógico)? ¡Ahora puede! Esta placa de conexión cuenta con el DAC de 12 bits MCP4725 fácil de usar. Contrólelo a través de I2C y envíele el valor que desea que emita, y el pin VOUT lo tendrá. Agotado € 5,85

Conectar

A continuación, se debe ajustar la conexión:
Coloque el pin 3 (A) de IC 1 en la salida del MCP4725 (VOU) (en lugar de en A5)
Coloque el pin 3 (A) de IC 2 en el pin A3 de la placa Arduino (en lugar de en A4).
Los pines A4 (SCA) y A5 (SCL) de la placa Arduino deben conectarse a SDA y SCL del MCP4725.
También conecte VDD y GND de la placa MCP4725 a 5V y GND respectivamente.
Conecte el pin A0 del MCP4725 a GND para seleccionar la dirección I2C 0x62.
(Alternativa: seleccione A0 a 5 V en la dirección 0x63).

Bibliotecas Adafruit

Para controlar el DAC Adafruit MCP4725, se recomienda descargar la biblioteca correspondiente de Adafruit .
Puede encontrarlos en Github.

El código para la prueba analógica es entonces el siguiente:

Test 74HC4051 MUX/DEMUX met Arduino Uno en DAC

// Voeg MCP4725 DAC bibliotheek toe
#include <Wire.h>               // I2C library
#include >Adafruit_MCP4725.h>   // Adafruit library for MCP4725 (DAC)
Adafruit_MCP4725 dac;

/****************************************************************
      Configuratie
****************************************************************/
#define pinS0   A0 // Address select 0
#define pinS1   A1 // Address select 1
#define pinS2   A2 // Address select 2
#define pinA_ic2  A3    // A pin on IC2
/*****   EINDE CONFIGUTATIE    *****/

// Poll timer
unsigned long lastPoll;

/****************************************************************
      SETUP
****************************************************************/
void setup()
{
  Serial.begin(115200);
  while (!Serial) {
    ; // Wacht op seriele monitor
  }
  Serial.println("--- Seriele monitor gestart ---");

  // Configureer pinnen als uitgangen
  pinMode(pinS0, OUTPUT);
  pinMode(pinS1, OUTPUT);
  pinMode(pinS2, OUTPUT);

  dac.begin(0x62);  // MCP4725, pin A0 ligt op GND
  // dac.begin(0x63);  // MCP4725, pin A0 ligt op 5V

  lastPoll = millis();
}

/****************************************************************
      LOOP
****************************************************************/
void loop()
{
  static byte byteCounter = 0;
  uint16_t writeChannel; // 12 bit (0-4095)
  uint16_t readChannel;  // 10 bit (0-1023)
  String testResult;

  // Genereer willekeurige analoge uitgang waarde
  writeChannel = random(0, 4096); // random 0-4095 (!)

  // Elke 500ms
  if (millis() - lastPoll >= 500)
  {
    // Selecteer adres
    selectAddress(byteCounter);

    // Schrijf naar DAC
    dac.setVoltage(writeChannel, false);

    // Lees analoge waarde van analoge ingang op Arduino
    readChannel = analogRead(pinA_ic2);

    // Converteer waarden naar volt
    writeChannel = map(writeChannel, 0, 4095, 0, 500);
    readChannel = map(readChannel, 0, 1023, 0, 500);

    // Zijn beide waarden gelijk ?
    if (writeChannel == readChannel) {
      testResult = " -> OK";
    }
    else {
      testResult = " -> NIET OK";
    }

    // In de seriële monitor moet schrijf waarde = lees waarde
    Serial.print("Op adres " );
    Serial.print(byteCounter, BIN);
    Serial.print(" is schrijf (IC 1) vs lees (IC 2): " );
    Serial.print(float(writeChannel)/100);
    Serial.print(" / ");
    Serial.print(float(readChannel)/100);
    Serial.print(testResult);
    Serial.println();

    // Selecteer volgend adres 
    byteCounter++;
    if (byteCounter > 7) {
      byteCounter = 0;  // Reset counter at 1000 (count 0000 to 0111)
    }
    lastPoll = millis();
  }
}

/****************************************************************
      Set the Sx pins to select proper address
****************************************************************/
void selectAddress(byte address) {
  // Lees adres bits
  bool S0 = bool(address >> 0 & 0x01); // Shift rechts en maskeer met 0x01
  bool S1 = bool(address >> 1 & 0x01);
  bool S2 = bool(address >> 2 & 0x01);

  // Zet adres lijnen correct
  digitalWrite(pinS0, S0);
  digitalWrite(pinS1, S1);
  digitalWrite(pinS2, S2);
}
//EINDE

El resultado en el monitor serial está en este género:

Op adres 10 is schrijf (IC 1) vs lees (IC 2): 3.40 / 3.40 -> OK
Op adres 11 is schrijf (IC 1) vs lees (IC 2): 4.21 / 4.21 -> OK
Op adres 100 is schrijf (IC 1) vs lees (IC 2): 0.08 / 0.08 -> OK
Op adres 101 is schrijf (IC 1) vs lees (IC 2): 1.54 / 1.54 -> OK
Op adres 110 is schrijf (IC 1) vs lees (IC 2): 1.53 / 1.53 -> OK
Op adres 111 is schrijf (IC 1) vs lees (IC 2): 4.02 / 4.02 -> OK
Op adres 0 is schrijf (IC 1) vs lees (IC 2): 0.82 / 0.82 -> OK
Op adres 1 is schrijf (IC 1) vs lees (IC 2): 0.93 / 0.93 -> OK
Op adres 10 is schrijf (IC 1) vs lees (IC 2): 3.72 / 3.72 -> OK
Op adres 11 is schrijf (IC 1) vs lees (IC 2): 1.35 / 1.35 -> OK
Op adres 100 is schrijf (IC 1) vs lees (IC 2): 2.64 / 2.64 -> OK
Op adres 101 is schrijf (IC 1) vs lees (IC 2): 1.29 / 1.29 -> OK
Op adres 110 is schrijf (IC 1) vs lees (IC 2): 2.89 / 2.88 -> NIET OK
Op adres 111 is schrijf (IC 1) vs lees (IC 2): 3.54 / 3.54 -> OK
Op adres 0 is schrijf (IC 1) vs lees (IC 2): 4.24 / 4.24 -> OK
Op adres 1 is schrijf (IC 1) vs lees (IC 2): 1.51 / 1.51 -> OK
Op adres 10 is schrijf (IC 1) vs lees (IC 2): 4.20 / 4.20 -> OK

Habrá "errores" ocasionales debido al redondeo y las imprecisiones. Por ejemplo, puede ver que 2,89 V no es igual a 2,88 V. Sin embargo, en combinación con todos los demás resultados exitosos, puede asumir que MUX/DEMUX funciona perfectamente.

Publicado por Arashi Sitio web

Probador Arduino Uno como 74HC4051 (MUX/DEMUX)

Prueba 74HC4051

asignación de pines

Pruebas digitales

Conectar

codigo Arduino

Test 74HC4051 MUX/DEMUX met Arduino Uno

Componentes

Lista de componentes

Pruebas analógicas

Conectar

Bibliotecas Adafruit

Test 74HC4051 MUX/DEMUX met Arduino Uno en DAC

Comentarios