Construir estación meteorológica

Colocado en 2019-04-30

Clave API
Se requiere una clave API para obtener información meteorológica. Para esto, debe registrar una cuenta con OpenWeatherMap, que se puede hacer aquí: https://home.openweathermap.org/users/sign_up. Una vez que esté registrado, vaya a la sección "Claves API". Copie la clave API que encuentre allí (Ver fotos).

Ir a "Claves API"

Copie la clave API

Instale la biblioteca ArduinoJson
Si ya tiene la última versión de la biblioteca ArduinoJson, puede omitir este paso.
Abra Arduino IDE, vaya a Sketch> Incluir biblioteca> Administrar bibliotecas (ver foto). Busque "arduinojson" e instale la última versión de la biblioteca ArduinoJson de Benoit Blanchon (ver foto).

Abra el administrador de la biblioteca

Descargar la biblioteca ArduinoJson

Instale la biblioteca LiquidCrystal I2C
Primero, descargue el archivo ZIP de la biblioteca desde este enlace: https://github.com/johnrickman/LiquidCrystal_I2C/archive/master.zip.
Luego vaya a Sketch -> Incluir biblioteca -> Agregar biblioteca .ZIP en el IDE Arduino y seleccione el archivo ZIP de la biblioteca.

Agregar el archivo ZIP

Instale las placas ESP8266
Si ya ha agregado las placas ESP8266 al IDE Arduino , puede omitir este paso.
Abra la configuración del IDE Arduino yendo a Archivo > Preferencias. En el cuadro de texto "URL del administrador de tableros adicionales", ingrese la URL "http://arduino.esp8266.com/stable/package_esp8266com_index.json" (ver foto). Luego abra el Administrador de tableros con Herramientas > Tablero > Administrador de tableros (ver foto). Luego instale las placas ESP8266 (ver foto).

Cambiar las "URL del administrador de tableros adicionales"

Abra el Administrador de la Junta

Instale las placas ESP8266

Averigüe la dirección I2C
Antes de cargar el código de la estación meteorológica, debe encontrar la dirección del módulo LCD I2C. Para hacer esto, use el siguiente código.

I2C scanner code

#include <Wire.h>
 
 
void setup()
{
  Wire.begin();
 
  Serial.begin(9600);
  Serial.println("\nI2C Scanner");
}
 
 
void loop()
{
  byte error, address;
  int nDevices;
 
  Serial.println("Scanning...");
 
  nDevices = 0;
  for(address = 1; address < 127; address++ )
  {
    Wire.beginTransmission(address);
    error = Wire.endTransmission();
 
    if (error == 0)
    {
      Serial.print("I2C device found at address 0x");
      if (address<16)
        Serial.print("0");
      Serial.print(address,HEX);
      Serial.println("  !");
 
      nDevices++;
    }
    else if (error==4)
    {
      Serial.print("Unknown error at address 0x");
      if (address<16)
        Serial.print("0");
      Serial.println(address,HEX);
    }    
  }
  if (nDevices == 0)
    Serial.println("No I2C devices found\n");
  else
    Serial.println("done\n");
 
  delay(5000);
}

En este caso la dirección es 0x3F

Subir código
Asegúrese de haber seleccionado la placa correcta en Herramientas -> Placa y que haya seleccionado el puerto correcto en Herramientas -> Puerto.
Ingrese su información y cargue el siguiente código a Wemos a través del IDE Arduino :

Weerstation code

#include <ESP8266WiFi.h>
#include <ArduinoJson.h>
#include <Wire.h>
#include <LiquidCrystal_I2C.h>
#include <WiFiUdp.h>

char ssid[] = "--VOER HIER DE NAAM VAN JE WIFI NETWERK IN--";
char pass[] = "--VOER HIER HET WACHTWOORD VAN JE WIFI NETWERK IN--";
String apiKey = "--VOER HIER JE API KEY IN--";
String city = "--VOER HIER DE NAAM VAN JE STAD OF DORP IN--";
int timeOffset = 7200; // 7200 voor zomertijd, 3600 voor wintertijd
int address = 0x3F; // Voer hier het I2C adres in van de vorige stap

// Ik raad aan niks onder deze regel te wijzigigen.

WiFiClient client;
LiquidCrystal_I2C lcd(address, 16, 2);
char servername[] = "api.openweathermap.org";
String result;
unsigned long weatherLast = millis();
unsigned long weatherInterval = 60000;

char ntpServer[] = "0.nl.pool.ntp.org";
WiFiUDP UDP;
IPAddress timeServerIP;
const int NTP_PACKET_SIZE = 48;
byte ntpBuffer[NTP_PACKET_SIZE];
uint32_t unixTime = 0;
unsigned long lastActualTime = 0;

void setup() {
  lcd.begin();
  lcd.backlight();
  lcd.noCursor();
  lcd.clear();
  lcd.print("Laden (WiFi)...");
  
  Serial.begin(9600);
  WiFi.begin(ssid, pass);
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
  }
  
  lcd.clear();
  lcd.print("Laden (NTP)...");

  UDP.begin(123);
  if(!WiFi.hostByName(ntpServer, timeServerIP)) {
   lcd.clear();
   lcd.print("NTP DNS fail");
   Serial.println("DNS lookup fail. Rebooting.");
   delay(1000); // Wacht even met rebooten
   ESP.reset();
  }
  sendNTPpacket(timeServerIP);

  /* Deze loop wacht op een NTP response */
  while(true) {
    uint32_t time = getTime();
    if(time) {
      unixTime = time;
      ntpLast = millis();
      break;
    }
  }

  lcd.clear();
  lcd.print("Laden (Data)...");
  getWeather();
}

void loop() {
  unsigned long currentMillis = millis();

  uint32_t actualTime = unixTime + (currentMillis - ntpLast) / 1000;
  if(lastActualTime - actualTime > 1000) {
    lastActualTime = actualTime;

    int hours = getHours(actualTime);
    int minutes = getMinutes(actualTime);
    int seconds = getSeconds(actualTime);
    lcd.setCursor(0, 0);
    if(hours < 10) {
      lcd.print("0");
    }
    lcd.print(hours);
    lcd.print(":");
    if(minutes < 10) {
      lcd.print("0");
    }
    lcd.print(minutes);
    lcd.print(":");
    if(seconds < 10) {
      lcd.print("0");
    }
    lcd.print(seconds);
  }

  if(currentMillis - weatherLast > weatherInterval) {
    getWeather();
  }
}

void getWeather() {
  if(!client.connect(servername, 80)) {
      lcd.clear();
      lcd.setCursor(0, 0);
      lcd.print("Verbinding");
      lcd.setCursor(0, 1);
      lcd.print("mislukt");
      Serial.println("Connection failed");
      weatherLast = millis();
      return;
   }

   client.println("GET /data/2.5/weather?q=" + city + "&APPID=" + apiKey + "&units=metric");
   client.println("Host: api.openweathermap.org");
   client.println("Connection: close");
   if(client.println() == 0) {
     lcd.clear();
     lcd.setCursor(0, 0);
     lcd.print("Kon request");
     lcd.setCursor(0, 1);
     lcd.print("niet sturen");
     Serial.println("Failed to send request");
     weatherLast = millis();
     return;
   }

   const size_t capacity = JSON_ARRAY_SIZE(3) + 2*JSON_OBJECT_SIZE(1) + JSON_OBJECT_SIZE(2) + 3*JSON_OBJECT_SIZE(4) + JSON_OBJECT_SIZE(5) + JSON_OBJECT_SIZE(6) + JSON_OBJECT_SIZE(12) + 340;
   DynamicJsonDocument doc(capacity);

   DeserializationError error = deserializeJson(doc, client);
   if (error) {
     lcd.clear();
     lcd.setCursor(0, 0);
     lcd.print("Kon JSON");
     lcd.setCursor(0, 1);
     lcd.print("niet verwerken");
     Serial.print("deserializeJson() failed: ");
     Serial.println(error.c_str());
     weatherLast = millis();
     return;
   }

   long temp = doc["main"]["temp"].as<double>();
   long humidity = doc["main"]["humidity"].as<long>();

   lcd.clear();
   lcd.setCursor(0, 1);
   lcd.print(temp);
   lcd.print("C | ");
   lcd.print(humidity);
   lcd.print("%");

   Serial.print("Temperature: ");
   Serial.print(temp);
   Serial.println(" C");
   Serial.print("Humidity: ");
   Serial.print(humidity);
   Serial.println("%");

   client.stop();
   weatherLast = millis();
}

uint32_t getTime() {
  if (UDP.parsePacket() == 0) {
    return 0;
  }
  UDP.read(ntpBuffer, NTP_PACKET_SIZE);
  uint32_t ntpTime = (ntpBuffer[40] << 24) | (ntpBuffer[41] << 16) | (ntpBuffer[42] << 8) | ntpBuffer[43];
  const uint32_t seventyYears = 2208988800UL;
  uint32_t unixTime = ntpTime - seventyYears;
  return unixTime + timeOffset;
}

void sendNTPpacket(IPAddress& address) {
  memset(ntpBuffer, 0, NTP_PACKET_SIZE);
  ntpBuffer[0] = 0b11100011;
  UDP.beginPacket(address, 123);
  UDP.write(ntpBuffer, NTP_PACKET_SIZE);
  UDP.endPacket();
}

inline int getSeconds(uint32_t unixTime) {
  return unixTime % 60;
}

inline int getMinutes(uint32_t unixTime) {
  return unixTime / 60 % 60;
}

inline int getHours(uint32_t unixTime) {
  return unixTime / 3600 % 24;
}

Pagina anterior 2. Hardware Página actual 3. Software Siguiente página 4. Resultado 1. Introducción 2. Hardware 3. Software 4. Resultado Publicado por Melluh Sitio web Soy desarrollador de software, pero también estoy muy interesado en la electrónica.

Construir estación meteorológica

I2C scanner code

Weerstation code

Comentarios