Arduino Leonardo - Cerradura Electrónica

Colocado en 2020-06-22

Falla el código en la memoria EEPROM

Ahora podemos obtener un código, verificarlo, pero ¿qué hay de guardarlo? Porque cuando reinicias el Arduino se borra la memoria RAM, así que tenemos que buscar otra forma de almacenarla y poder cambiarla sin tener que volver a cargar el programa. Aquí es donde interviene la EEPROM en el juego...

Así que tenemos que usar la biblioteca EEPROM.

Storing and Getting the code from EEPROM

#include <EEPROM.h>

unsigned char Eeprom_PasscodeLength = 0;

void GetEepromCode() {
   EEPROM.get(0, Eeprom_PasscodeLength);
   if (Eeprom_PasscodeLength) {
      NewPasscodeLength = Eeprom_PasscodeLength;
      for (unsigned char i = 0; i < Eeprom_PasscodeLength; i++) {
        EEPROM.get(i + 1, Master[i]);
      }
   }
   else {
    NewPasscodeLength = PasscodeLength;
    return;
   }
   PasscodeLength = NewPasscodeLength;
}

void WriteEepromCode(){
  EEPROM.put(0, PasscodeLength);
  for (unsigned char i = 0; i < PasscodeLength; i++) {
    EEPROM.put(i + 1, Master[i]);
  }
}

Entonces, ahora podemos almacenar y obtener un código de la EEPROM, es hora de habilitarlo para cambiar el código mientras el programa aún se está ejecutando en Arduino .

Changing the code while the program is running

void CheckNewCode() {
  if (EnableDebug) {
    Serial.print("dataCountBuff1: ");
    Serial.println(dataCountBuff1);
    Serial.print("dataCountBuff2: ");
    Serial.println(dataCountBuff2);
    Serial.print("codeBuff1: ");
    Serial.println(code_buff1);
    Serial.print("codeBuff2: ");
    Serial.println(code_buff2);
  }  
  if (dataCountBuff1 == dataCountBuff2) {
      if(!strcmp(code_buff1, code_buff2)){
          NewPasscodeLength = dataCountBuff2;
          for (unsigned char i = 0; i <= MaxPasscodeLength; i++) {
            Master[i] = 0;
          }
          
          for (unsigned char i = 0; i <= NewPasscodeLength; i++) {
            Master[i] = code_buff1[i];
          }

          if (EnableDebug) {
            Serial.println();
            Serial.print("Master: ");
            Serial.println(Master);
          }
          lcd.clear();
          lcd.print("Passcodes Match");
          _delay_ms(1000);
          lcd.clear();
        }
     else {
        NewPasscodeLength = PasscodeLength;
        lcd.clear();
        lcd.setCursor(0,0);
        lcd.print("Codes do not match");
        if (EnableDebug) {
          Serial.println();
          Serial.println("Passcodes do not match");
        }
        _delay_ms(1000);
        lcd.clear();
     }
  }
  else {
    NewPasscodeLength = PasscodeLength;
    lcd.clear();
    lcd.setCursor(0,0);
    lcd.print("Codes do not match");
    if (EnableDebug) {
      Serial.println();
      Serial.println("Passcodes are not the same length");
    }
    _delay_ms(1000);
    lcd.clear();
  }
  clearData();
}

void ChangeCode() {
    dataCountBuff1 = 0;
    dataCountBuff2 = 0;
    for (unsigned char i = 0; i <= MaxPasscodeLength; i++) {
      code_buff1[i] = 0;
      code_buff2[i] = 0;
    }
    if (EnableDebug) {
      Serial.println();
      Serial.println("Changing Master");
    }
    lcd.clear();
    lcd.print("Enter new code:");
    lcd.setCursor(0,2);
    lcd.print("press * to confirm");
    Key = WaitForKey();
    while(Key != '*') {
      GetCode();
      Key = WaitForKey();
    }
    Data[data_count] = 0;
    dataCountBuff1 = data_count;
    for (unsigned char i =0; i <= data_count; i++) {
      code_buff1[i] = Data[i];
    }
    clearData();
    lcd.clear();
    _delay_ms(500);
    lcd.print("Confirm new code:");
    lcd.setCursor(0,2);
    lcd.print("press * to confirm");
    Key = WaitForKey();
    while (Key != '*') {
      GetCode();
      Key = WaitForKey();
    }
    Data[data_count] = 0;
    dataCountBuff2 = data_count;
    for (unsigned char i =0; i <= data_count; i++) {
      code_buff2[i] = Data[i];
    }
    clearData();
    CheckNewCode();
    PasscodeLength = NewPasscodeLength;
    if (EnableDebug) {
      Serial.print("PasscodeLength: ");
      Serial.println(PasscodeLength);
    }
    WriteEepromCode();
}

Arduino Leonardo - Cerradura Electrónica

Falla el código en la memoria EEPROM

Storing and Getting the code from EEPROM

Changing the code while the program is running

Comentarios